// Beyond the Digital Zone System Zone Ruler macro for ImageJ

// Requires Color_Transformer_2.class.

// This macro measures the mean L* values and signal-to-noise ratios (mean / standard deviation)
// of an exposure series, stitches the images into a zone ruler, and displays a simple plot.

// Images should be small crops of out-of-focus photographs of a uniform surface,
// about 50-100 pixels square.  (The SNR “reference image” is just pixels of the mean value.)
// Use 8- or 16-bit RGB .tif, .jpg, .png, .gif, or .bmp images.
// Place them into a folder, run the macro, and select the folder.
// You will be prompted to choose the lowest zone in the image series, and the images’ color space.

// Custom color spaces may be added to Color Transformer 2.  However, as exposure series images generally
// occupy a very small gamut, and L* is all that is being measured, another profile with the same gamma
// (such as Adobe RGB for 2.2, ProPhoto RGB for 1.8) will probably do.

// 2/22/2014 by Russell Cottrell.  Please visit russellcottrell.com/photo/BTDZS/ .



macro "BTDZS Zone Ruler" {

setBatchMode(true);

dir = getDirectory("Choose an Image Folder");
dirName = File.getName(dir);
bigList = getFileList(dir);
list = newArray();
LL = bigList.length;

for (i=0; i<LL; i++) {
	bli = toLowerCase(bigList[i]);
	if (endsWith(bli, ".tif") ||
	    endsWith(bli, ".tiff") ||
	    endsWith(bli, ".jpg") ||
	    endsWith(bli, ".jpeg") ||
	    endsWith(bli, ".png") ||
	    endsWith(bli, ".gif") ||
	    endsWith(bli, ".bmp"))
		list = Array.concat(list, bigList[i]); }

LL = list.length;
resultsArr = newArray(LL);
rankPosArr = newArray(LL);

lowestZones = newArray("-IV", "-III", "-II", "-I", "O", "I", "II", "III", "IV");

RGBcolourspaces = newArray("sRGB",
                           "Adobe RGB",
                           "ProPhoto RGB",
                           "eciRGB v2",
                           "Custom"); // which is Pro Photo 2.2 5500.  It’s what I use.

Dialog.create(dirName);
icString = toString(LL, 0) + " image";
if (LL != 1)
	icString = icString + "s";
Dialog.addMessage(icString + ".");
Dialog.addChoice("Lowest zone in the image series: ", lowestZones, lowestZones[4]);
Dialog.addChoice("The images' color space: ", RGBcolourspaces);
Dialog.addMessage("Or choose a space with the same gamma, such as\nAdobe RGB for 2.2, ProPhoto RGB for 1.8.");
Dialog.show();
lowestZone = Dialog.getChoice();
for (i=0; i<lowestZones.length; i++) {
	if (lowestZone == lowestZones[i])
		lowestZone = i - 4; }
RGBcolourspace = Dialog.getChoice();

if (LL > 0) {

for (i=0; i<LL; i++) {
	open(dir + list[i]);
	resultsArr[i] = getInfo("image.filename");

	if (bitDepth() == 16) {
		setSlice(3);				// set 16-bit range
		setMinAndMax(0, 65535);
		setSlice(2);
		setMinAndMax(0, 65535);
		setSlice(1);
		setMinAndMax(0, 65535);
		run("RGB Color");			// convert to RGB color
		t = getTitle();
		selectWindow(list[i]);
		close();
		selectWindow(t);
		rename(list[i]); }

	run("Color Transformer 2", "from=[" + RGBcolourspace + "] to=Lab convert display");
	setSlice(3);
	run("Delete Slice");
	setSlice(2);
	run("Delete Slice");
	getStatistics(area, mean, min, max, std);
	resultsArr[i] = resultsArr[i] + "|" + toString(mean, 2) + "|" + toString(mean/std, 2);

	rankPosArr[i] = mean;

	close();

	showProgress(i, LL); }

rankPosArr = Array.rankPositions(rankPosArr);		// rank measurements by mean
newImage("ruler", "RGB", 1, 1, 1);

for (i=0; i<LL; i++) {					// construct the ruler
	listRankPos = list[rankPosArr[i]];

	selectWindow(listRankPos);
	getDimensions(iW, iH, channels, slices, frames);

	selectWindow("ruler");
	getDimensions(rW, rH, channels, slices, frames);
	if (rW == 1)
		rW = 0;
	run("Canvas Size...", "width=" + (iW + rW) + " height=" + maxOf(iH, rH) + " position=Top-Left");
	run("Add Image...", "image=[" + listRankPos + "] x=" + rW + " y=0 opacity=100");

	selectWindow(listRankPos);
	close();

	showProgress(i, LL); }

selectWindow("ruler");
run("Flatten");
rename("ruler - " + dirName);

selectWindow("ruler");
close();

setBatchMode("exit and display");

if (LL > 3) {						// plot the values

xValues = newArray();
for (i=0; i<LL; i++)
	xValues = Array.concat(xValues, lowestZone + i);

yValues = newArray();  // L*
y2Values = newArray(); // SNR
for (i=0; i<LL; i++) {
	outputArr = split(resultsArr[rankPosArr[i]], "|");
	yValues = Array.concat(yValues, outputArr[1]);
	y2Values = Array.concat(y2Values, outputArr[2]); }

Plot.create("plot - " + dirName, "Zone", "L*  /  SNR");

Plot.setLimits(lowestZone, lowestZone + LL - 1, 0, 100);

frameWidth = 700;
if (LL > 12)
	frameWidth = frameWidth + (64 * (LL-12));
else if (LL < 7)
	frameWidth = frameWidth - (116 * (7-LL));

Plot.setFrameSize(frameWidth, 450);

Plot.setJustification("center");

Plot.addText("Zone " + toString(lowestZone + 1, 0), 1/(LL-1), 0.6);
Plot.addText("Zone " + toString(lowestZone + LL - 2, 0), (LL-2)/(LL-1), 0.25);

Plot.setColor("red");
Plot.setLineWidth(6);
Plot.add("dots", xValues, y2Values);
Plot.setLineWidth(2);
Plot.add("line", xValues, y2Values);
Plot.addText("SNR " + toString(y2Values[1]), 1/(LL-1), 0.7);

Plot.setColor("blue");
Plot.setLineWidth(6);
Plot.add("dots", xValues, yValues);
Plot.setLineWidth(2);
Plot.add("line", xValues, yValues);
Plot.addText("L* " + toString(yValues[1]), 1/(LL-1), 0.65);
Plot.addText("L* " + toString(yValues[LL-2]), (LL-2)/(LL-1), 0.3);

Plot.setLineWidth(1);

Plot.show();

}

for (i=0; i<LL; i++) {					// display the values
	outputArr = split(resultsArr[rankPosArr[i]], "|");
	row = nResults();
	setResult("File Name", row, outputArr[0]);
	setResult("L* Mean", row, outputArr[1]);
	setResult("SNR", row, outputArr[2]);
	updateResults(); }

IJ.renameResults("results - " + dirName);

}

}